home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / yase.arc / EDIT1.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-12-13  |  3.9 KB  |  114 lines
  1. ******************************************************************
  2. * COPYRIGHT (C) 1986 by Donald Krantz and James Stanley
  3. * - Note: This is a real, live, actual, registered copyright,
  4. *   and should be treated as such. This source code is from
  5. *   the book "68000 Assembly Language", Krantz and Stanley,
  6. *   Addison-Wesley Publishing Company, Reading, MA, 1986.
  7. * 
  8. *   Permission granted by the authors for non-commercial use
  9. *   in programs released to the public domain, as long as this
  10. *   copyright notice remains attached and visible.
  11. *
  12. *****************************************************************
  13. * EDIT1 - Editor file I/O routines.
  14. *
  15. * Routines:    READ_IN    Reads a file into an editing buffer.
  16. *         Entry:    Register A5.L points to an initialized
  17. *            edit buffer descriptor block.
  18. *            Register A0.L points to filename string
  19. *         Exit:    ed_err(a5) set if any problems.
  20. *
  21. *        WRITE_OUT writes a block of memory data to a
  22. *            file. 
  23. *         Entry:    Register A0.L points to filename string.
  24. *            Register A1.L points to the start of data
  25. *            area in memory. D1.W holds number of 
  26. *            bytes to write into file.
  27. *        Exit:    ed_err(a5) set if any problems.
  28.  
  29.     .xref     open,close,fgetc,fputc
  30.     .xdef    read_in,write_out
  31.  
  32. #fcb.h
  33. #edit.h
  34.  
  35. *****************************************************************
  36. * READ_IN - Reads a file into an editing buffer.
  37. read_in:
  38.     movem.l    d1/a0/a1,-(a7)    * Save caller's registers.
  39.     link    a6,#-file    * Create an FCB on the stack
  40.     move.l    a7,a1        * get FCB address
  41.     move.w    #0,-(a7)    * Push 0 for "File Must Exist"
  42.     move.l    a0,-(a7)    * Push filename
  43.     move.l    a1,-(a7)    * Push FCB address
  44.     bsr    open        * Attempt open
  45.     tst.w    d0        * Did it work?
  46.     bpl    sk1_read    * Yes.
  47.     move.w    #1,d0        * Show "File-not-found" error
  48.     bra    read_exit    * Say goodbye.
  49. sk1_read:
  50.     move.l    e_gap(a5),d1    * Compute buffer length
  51.     sub.l    b_gap(a5),d1    
  52.     move.l    b_gap(a5),a1    * Setup pointer to data area
  53.     bra    sk3_read    * Loop test done before read
  54. lp1_read:
  55.     bsr    fgetc        * Read character
  56.     tst.w    d0        * Look for end of file
  57.     bmi    sk2_read    * Yes, found end-of-file
  58.     cmp.b    #13,d0        * is this C/R?
  59.     beq    lp1_read    * yes, just skip it.
  60.     move.b    d0,(a1)+    * Store datum
  61. sk3_read:
  62.     dbra    d1,lp1_read    * Go for the next one.
  63.     move.w    #2,d0        * If we're here, file's too big.
  64.     bra    read_exit    * So leave.
  65. sk2_read:
  66.     move.l    a1,b_gap(a5)    * save in descriptor structure
  67.     move.w    #0,d0        * Show successful read.
  68. read_exit:
  69.     unlk    a6        * Restore frame pointer
  70.     movem.l    (a7)+,d1/a0/a1    * Restore caller's registers.
  71.     rts
  72. *****************************************************************
  73. * WRITE_OUT - writes a file to disk
  74. write_out:
  75.     movem.l    d1/a0-a2,-(a7)    * Save caller's registers.
  76.     link    a6,#-file    * Create an FCB on the stack
  77.     move.l    a7,a2        * Get FCB address
  78.     move.w    #$FFFF,-(a7)    * Push -1 for "Create File"
  79.     move.l    a0,-(a7)    * Push filename
  80.     move.l    a2,-(a7)    * Push FCB address
  81.     bsr    open        * Attempt open
  82.     tst.w    d0        * Did it work?
  83.     bpl    sk4_write    * Yes, loop test before write.
  84.     move.w    #1,d0        * Show "Can't make file" error
  85.     bra    write_exit    * Say goodbye.
  86. lp1_write:
  87.     cmp.b    #10,(a1)    * Is this a newline?
  88.     bne    sk3_write    * No.
  89.     move.b    #13,5(a7)    * Store RETURN into stack
  90.     bsr    fputc        * write RETURN.
  91.     tst.w    d0        * Look for error.
  92.     bmi    sk2_write    * Yes, found error.
  93. sk3_write:
  94.     move.b    (a1)+,5(a7)    * Store parameter into stack
  95.     bsr    fputc        * write character
  96.     tst.w    d0        * Look for error.
  97.     bmi    sk2_write    * Yes, found error.
  98. sk4_write:
  99.     dbra    d1,lp1_write    * Go for the next one.
  100.     move.l    a2,-(a7)    * push FCB address
  101.     bsr    close        * close file
  102.     tst.w    d0        * smooth return code
  103.     bmi    write_exit    * error exit
  104.     clr.w    d0        * show success
  105.     bra    write_exit    * and get out of here.
  106. sk2_write:
  107.     move.w    #1,d0        * Show error.
  108. write_exit:
  109.     unlk    a6        * Restore frame pointer
  110.     movem.l    (a7)+,d1/a0-a2    * Restore caller's registers.
  111.     rts
  112.  
  113.     end
  114.